VBAで複数フォルダを階層別に一括作成｜エクセルマクロでサブフォルダも生成

作成したフォルダ数が5程度であれば、手入力で作成することでも問題ありません。

しかし作成したいフォルダ数が数10個以上作る場合、マクロを使った方が早いです。

実際マクロを使えば、10コでも100コでも自動で処理を行うことができます。また、フォルダ名を間違えずに作成することができます。

・VBAでエクセルのデータをもとに複数フォルダを階層別に作成

・VBAプログラム入りのエクセルファイルをダウンロード可能

このページでは、マクロで複数フォルダを階層別に作成するプログラムを紹介します。

またVBAプログラムが含まれたエクセルファイルをダウンロードすることもできるようにしていますので、興味がある人はご活用ください。

1 概要｜複数フォルダを階層別にまとめて一括作成するマクロとは？
- 1.1 動画で解説
2 手順｜複数フォルダを階層別にまとめて一括作成するマクロの使い方
3 VBA入りのエクセルファイルをダウンロード
4 VBA作成前の2つの事前準備
- 4.1 準備1. ExcelでVBAを使うための事前準備
- 4.2 準備2. フォルダを扱うための事前準備
5 VBAのプログラムソース解説
6 VBAでフォルダ操作する事例
- 6.1 本サイトで紹介しているVBAプログラムと解説ページ
7 Excel VBAについて詳しく理解したいなら
- 7.1 VBAの勉強方法

概要｜複数フォルダを階層別にまとめて一括作成するマクロとは？

あるフォルダの中に、複数の子フォルダを作成したいときがあります。

例えば、以下の画像のようにとあるフォルダにエクセルファイルが一つだけあるとします。

ここに子フォルダはありません。

このフォルダに階層別に子フォルダを作るとします（以下はイメージ）。

このとき、以下のようにフォルダを手入力で作成していくことは可能です。

動画で解説

このページで紹介するマクロは、以下の動画で説明しています。

動画の中では、「クリア」ボタンが設定されています。しかし、機能を持っていないため、説明をしていません。

手順｜複数フォルダを階層別にまとめて一括作成するマクロの使い方

この記事で紹介するマクロについて説明していきます。

手順1｜作成先のフォルダパスを入力

手順2｜階層別に作成したいフォルダ名をエクセルを入力

手順3｜ボタン(VBAプログラム入り)を押下

上記の手順を行うと、手順1で指定したフォルダパスに、手順2で入力したフォルダが自動で作成されます。

以下で各手順について詳細を説明します。

手順1｜作成先のフォルダパスを入力

セルB2にフォルダパスを入力します。

ここで指定したフォルダパスに新しいフォルダ(子フォルダ含む)を作成します。

なおセルB2に入力するフォルダパスが存在しない場合、VBAプログラムはエラーとなります。

手順2｜階層別に作成したいフォルダ名をエクセルを入力

上記の画像のように、階層別に作成したいフォルダ名をエクセルに入力していきます。

ここで入力した名前でフォルダを作成します。

注意点

1. 各行に2つ以上のフォルダ名を入力しないこと

2. 階層がずれないようにすること

注意点1. 各行に2つ以上のフォルダ名を入力しないこと

各行に1つずつフォルダ名を入力しないとプログラムエラーが出ます。

注意点2. 階層がずれないようにすること

フォルダの階層がずれないようにします。

上記の画像ではフォルダ階層2が存在しないまま、フォルダ階層3を入力しているため、プログラムエラーが出ます。

手順3｜ボタン(VBAプログラム入り)を押下

ボタンを押すと、プログラムが実行されて、フォルダが自動作成されます。

フォルダが自動作成された結果は以下の画像のとおりです。

以上が手順です。

VBA入りのエクセルファイルをダウンロード

このページで紹介しているエクセルファイル(VBAプログラム入り)をそのまま使いたい人は、以下のフォームからダウンロードできます。

登録したメールアドレスへ「VBAプログラムが含まれたエクセル」を送信します。

本プログラムの内容をそのまま使用可能です。ぜひお仕事にお役立てください。

読み込んでいます…

それでは以下で本ページで紹介しているVBAプログラムについて説明します。

VBA作成前の2つの事前準備

ExcelでVBAを使うためにはいくつかの準備が必要です。

具体的には以下です。

1. ExcelでVBAを使うための事前準備

2. フォルダを扱うための事前準備

上記の2つに関して、以下で説明します。

準備1. ExcelでVBAを使うための事前準備

エクセルVBAを使うためには、保存ファイルの拡張子変更、Excelの基本設定変更の2つをしておきます。

2つともで難しい作業はなく、それぞれ1分もあれば設定変更可能です。

上記に関しては、以下の記事で解説をしています。

エクセルマクロ使い方｜編集方法をVBA作成から保存のやり方まで解説

これからエクセルマクロを勉強しようとする人にとって、マクロの編集は一つのカベです。マクロというこれまで触ったことのないものを操作できるようになるのは決して簡単なことではありません。しかし順序良く学んでいけば、難しいも […]

もしVBAを使うための準備段階に不安がある人は上記をご覧ください。

この内容は以下の動画で紹介しています。

入門エクセルマクロの使い方｜マクロ作成から実行までを徹底解説

文字や画像だけで分かりづらい人は上記の動画をご覧ください。

準備2. フォルダを扱うための事前準備

この事例ではフォルダを操作するために、FileSystemObjectを活用します。

FileSystemObjectを使用する場合、VBAの参照設定を変更しておく必要があります。参照設定とは、機能拡張させることです。

FileSystemObjectを使用するために以下の参照設定を変更します。

「Microsoft Scripting Runtime」にチェックを入れる

これでフォルダやファイルの情報を取得することができるようになります。

設定方法の詳細は以下のページで紹介しています。

VBAのFSO(FileSystemObject)とは？参照設定や使えないときの対処法からメソッドや事例まで

VBAでフォルダやファイルを操作するとき、FSO(FileSystemObject)を設定すると便利です。このページではFileSystemObjectを使うために必要な設定(参照設定の方法)を紹介します。また参照設 […]

なお「Microsoft Scripting Runtime」にチェックを入れていないと、本事例で紹介しているVBAプログラムは動作しません。

必ずチェックを入れるようにします。

VBAのプログラムソース解説

今回紹介するプログラムの概要は以下です。

'プログラム0｜変数宣言の指定
Option Explicit

'プログラム1｜プログラム開始
Sub CreatefoldersWithSubfolders()
    
    'プログラム2｜変数設定
    Dim i As Long, cmax As Long, x As Long, z As Long, cnt As Long, j As Long, k As Long, n1 As Long
    Dim str As String, url As String, s As String, s1 As String
    
    'プログラム3｜FileSystemObjectを設定
    Dim fs As FileSystemObject
    Set fs = New Scripting.FileSystemObject
    
    'プログラム4｜対象シートを設定
    Dim ws1 As Worksheet
    Set ws1 = Worksheets("フォルダ作成")
    
    'プログラム5｜セル範囲を指定
    cmax = ws1.Range("A65536").End(xlUp).Row
    cnt = ws1.Range("IV4").End(xlToLeft).Column
    
    'プログラム6｜セルB2にURLが記載されているかチェック
    If ws1.Range("B2").Value = "" Then
        MsgBox "セルB2に「作成先のフォルダURL」を入力して下さい"
        Exit Sub
    End If
    url = ws1.Range("B2").Value
    
    'プログラム7｜Excelの記載チェック（同じ行に複数回記入されていないことを確認）
    For i = 5 To cmax
        x = 0
        
        For j = 0 To cnt - 2
            If ws1.Range("B" & i).Offset(0, j).Value <> "" Then
                x = x + 1
            End If
        Next
        
        If x > 1 Then
            z = z + 1
        End If
    Next
    
    'プログラム8｜同じ行に複数回記入されていた場合、処理を止める
    If z > 0 Then
        MsgBox "入力情報を見直してください"
        Exit Sub
    End If
    
    'プログラム9｜階層別にフォルダを作成する
    For j = 0 To cnt - 2
        For i = 5 To cmax
            s = ""
            
            If ws1.Range("B" & i).Offset(0, j).Value <> "" Then
                s1 = ws1.Range("B" & i).Offset(0, j).Value
                
                For k = 0 To j
                    If k - j = 0 Then
                        Exit For
                    End If
                    
                    n1 = ws1.Range("B" & i).Offset(0, j - k - 1).End(xlUp).Row
                    s1 = ws1.Range("B" & n1).Offset(0, j - k - 1).Value & "\" & s1
                Next
                
                s = url & "\" & s1
                If fs.FolderExists(folderspec:=s) = False Then
                    fs.Createfolder s
                End If
    
            End If
        Next
    Next

    'プログラム10｜オブジェクト解放
    Set fs = Nothing
    
'プログラム11｜プログラム終了
End Sub

'プログラム0｜変数宣言の指定

Option Explicit

'プログラム1｜プログラム開始

Sub CreatefoldersWithSubfolders()

'プログラム2｜変数設定

Dim i As Long, cmax As Long, x As Long, z As Long, cnt As Long, j As Long, k As Long, n1 As Long

Dim str As String, url As String, s As String, s1 As String

'プログラム3｜FileSystemObjectを設定

Dim fs As FileSystemObject

Set fs = New Scripting.FileSystemObject

'プログラム4｜対象シートを設定

Dim ws1 As Worksheet

Set ws1 = Worksheets("フォルダ作成")

'プログラム5｜セル範囲を指定

cmax = ws1.Range("A65536").End(xlUp).Row

cnt = ws1.Range("IV4").End(xlToLeft).Column

'プログラム6｜セルB2にURLが記載されているかチェック

If ws1.Range("B2").Value = "" Then

MsgBox "セルB2に「作成先のフォルダURL」を入力して下さい"

Exit Sub

End If

url = ws1.Range("B2").Value

'プログラム7｜Excelの記載チェック（同じ行に複数回記入されていないことを確認）

For i = 5 To cmax

x = 0

For j = 0 To cnt - 2

If ws1.Range("B" & i).Offset(0, j).Value <> "" Then

x = x + 1

End If

If x > 1 Then

z = z + 1

End If

'プログラム8｜同じ行に複数回記入されていた場合、処理を止める

If z > 0 Then

MsgBox "入力情報を見直してください"

Exit Sub

End If

'プログラム9｜階層別にフォルダを作成する

For j = 0 To cnt - 2

For i = 5 To cmax

s = ""

If ws1.Range("B" & i).Offset(0, j).Value <> "" Then

s1 = ws1.Range("B" & i).Offset(0, j).Value

For k = 0 To j

If k - j = 0 Then

Exit For

End If

n1 = ws1.Range("B" & i).Offset(0, j - k - 1).End(xlUp).Row

s1 = ws1.Range("B" & n1).Offset(0, j - k - 1).Value & "\" & s1

s = url & "\" & s1

If fs.FolderExists(folderspec:=s) = False Then

fs.Createfolder s

End If

'プログラム10｜オブジェクト解放

Set fs = Nothing

'プログラム11｜プログラム終了

End Sub

以下で詳しく説明します。

プログラム0｜変数宣言の指定

Option Explicit

1	Option Explicit

「Option Explicit」とは、変数宣言を強制するためのものです。

予期しないエラーを防止できるため「Option Explicit」を入力することを習慣化することを推奨しています。

詳しい説明は以下のページで紹介しています。

エクセルマクロVBAのOption Explicitとは？設定方法と宣言する理由

エクセルマクロVBAではOption Explicitを設定すると変数宣言を強制させることができます。 Option Explicitは入力しておくと、変数宣言が必須になります。そのせいで変数宣言していないとエラー表示が […]

プログラム1｜プログラム開始

Sub CreatefoldersWithSubfolders()

1	Sub CreatefoldersWithSubfolders()

プログラム「Sub CreatefoldersWithSubfolders()」を実行するという意味です。

VBAではプロシージャという単位でプログラムを呼び出します。

プロシージャの構文は下記となっています。

Sub プロシージャ名()
    '実行プログラム
End Sub

Sub プロシージャ名()

'実行プログラム

End Sub

「Sub」で始まり「End Sub」で終わります。

プロシージャに関連するmoduleの話については以下で説明しています。

エクセルマクロVBAの標準モジュールを解説｜名前変更/削除/呼び出し/実行/コピー/複数作成/表示など

エクセルマクロVBAでは、標準モジュールを使ってプログラムを作成します。しかしマクロを使い始めたばかりだと、標準モジュールの使い方が分からず困ってしまうことがあります。そこで、エクセルマクロVBA初心者が標準モジュー […]

プログラム2｜変数設定

    Dim i As Long, cmax As Long, x As Long, z As Long, cnt As Long, j As Long, k As Long, n1 As Long
    Dim str As String, url As String, s As String, s1 As String

1 2	Dim i As Long, cmax As Long, x As Long, z As Long, cnt As Long, j As Long, k As Long, n1 As Long Dim str As String, url As String, s As String, s1 As String

本プログラムで使用する変数を設定します。

Long(整数)型とString(文字列)型の2種類を使って、本プログラムを動かします。

参考情報

変数については、以下のページで紹介しています。

VBAの変数とは？型や初期値からメリットや使う意義まで解説

VBAでは変数を使うとき、最初に変数を定義すると便利です。このページでは変数を定義する方法や、変数名の付け方などについて解説します。上記の動画で変数について解説していますので、イメージを掴みたい人はご覧ください。以 […]

プログラム3｜FileSystemObjectを設定

    Dim fs As FileSystemObject
    Set fs = New Scripting.FileSystemObject

1 2	Dim fs As FileSystemObject Set fs = New Scripting.FileSystemObject

FileSystemObjectは、ファイルやフォルダを操作するときに使うオブジェクトです。

本事例ではFileSystemObjectをfsという変数として扱います。

変数fsは定義するだけではなく、「Set fs = New Scripting.FileSystemObject」と記入して使えるようになります。

これを忘れてしまうことが多いので、注意が必要です。

FileSystemObjectに関する注意点

なお参照設定にて、Microsoft Scripitng Runtimeを設定に入れておく必要があります。

設定を忘れると動作しませんので、事前に設定を変更しておく必要があります。

なお、FileSystemObject以外にもフォルダを操作する方法はあります。しかしFileSystemObjectを使えば、ファイルとフォルダを両方操作できるので、覚えることが少なくて済みます。

細かいことを覚えるのが面倒な人は、ファイルやフォルダを操作するときはFileSystemObjectを使うと覚えておくといいです。

FileSystemObjectに関しては以下で詳しく紹介しています。

VBAのFSO(FileSystemObject)とは？参照設定や使えないときの対処法からメソッドや事例まで

プログラム4｜対象シートを設定

    Dim ws1 As Worksheet
    Set ws1 = Worksheets("フォルダ作成")

1 2	Dim ws1 As Worksheet Set ws1 = Worksheets("フォルダ作成")

変数ws1をWorksheet(ワークシート)型で設定します。

そして、シート「フォルダ作成」をws1として扱います。

プログラム5｜セル範囲を指定

    cmax = ws1.Range("A65536").End(xlUp).Row
    cnt = ws1.Range("IV4").End(xlToLeft).Column

1 2	cmax = ws1.Range("A65536").End(xlUp).Row cnt = ws1.Range("IV4").End(xlToLeft).Column

cmaxは、シート「フォルダ作成」のA列の最終行を取得します。今回はA54のセルまで値が入力されているため、cmax=54です。

cntは、4行目の最右列を取得します。今回はG4のセルまで入力されているため、cnt=7です。(A,B,C,D,E,F,Gと数えるとき、Gが7番目のため、cnt=7)

プログラム6｜セルB2にURLが記載されているかチェック

    If fs.FolderExists(folderspec:=Range("B2").Value) = False Then
        MsgBox "セルB2に「作成先のフォルダURL」を入力して下さい"
        Exit Sub
    End If
    url = ws1.Range("B2").Value

If fs.FolderExists(folderspec:=Range("B2").Value) = False Then

MsgBox "セルB2に「作成先のフォルダURL」を入力して下さい"

Exit Sub

End If

url = ws1.Range("B2").Value

セルB2にフォルダパスが入力されていなければ、エラーメッセージ「セルB2に「作成先のフォルダURL」を入力して下さい」が出るようにします。

「If fs.FolderExists(folderspec:=Range(“B2”).Value) = False then」で「セルB2の値で指定したフォルダパスが存在しなければ」という意味です。

このプログラムを使って、セルB2にフォルダパスが正しく入力されていることを検証します。

もしフォルダパスが正しくなければ、「Exit Sub」でプログラムを強制終了させます。

問題なければ、変数urlにセルB2の値(フォルダパス)を入力します。

参考情報

フォルダの存在チェックは以下で詳しく説明しています。

VBAでFSOを使ってフォルダ存在チェックしてフォルダ作成

'FileSystemObjectの設定 Dim fs As Scripting.FileSystemObject Set fs = New Scripting.FileSystemObject 'フォルダパスを取得 D […]

プログラム7｜Excelの記載チェック（同じ行に複数回記入されていないことを確認）

    For i = 5 To cmax
        x = 0
        
        For j = 0 To cnt - 2
            If ws1.Range("B" & i).Offset(0, j).Value <> "" Then
                x = x + 1
            End If
        Next
        
        If x > 1 Then
            z = 1
        End If
    Next

For i = 5 To cmax

x = 0

For j = 0 To cnt - 2

If ws1.Range("B" & i).Offset(0, j).Value <> "" Then

x = x + 1

End If

If x > 1 Then

z = 1

End If

同じ行に2つ以上のフォルダ名が入力されていると、正しくフォルダを作成できません。

そのため、同じ行に2つ以上のフォルダ名がエクセルに入力されている場合、エラーメッセージが出るようにします。

今回は変数zを判定値として使います。

もし同じ行に2つ以上のフォルダ名がエクセルに入力されている場合、z=1となるようにします。

この変数zの値を使ってプログラム8でエラーメッセージが出すかどうかを決定します。

プログラム8｜同じ行に複数回記入されていた場合、処理を止める

    If z = 1 Then
        MsgBox "入力情報を見直してください"
        Exit Sub
    End If

If z = 1 Then

MsgBox "入力情報を見直してください"

Exit Sub

End If

プログラム7で変数zが1なら、「入力情報を見直してください」というエラーメッセージが出力されます。

そして「Exit Sub」でプログラムを強制終了させます。

プログラム9｜階層別にフォルダを作成する

    For j = 0 To cnt - 2
        For i = 5 To cmax
            s = ""
            
            If ws1.Range("B" & i).Offset(0, j).Value <> "" Then
                s1 = ws1.Range("B" & i).Offset(0, j).Value
                
                For k = 0 To j
                    If k - j = 0 Then
                        Exit For
                    End If
                    
                    n1 = ws1.Range("B" & i).Offset(0, j - k - 1).End(xlUp).Row
                    s1 = ws1.Range("B" & n1).Offset(0, j - k - 1).Value & "\" & s1
                Next
                
                s = url & "\" & s1
                If fs.FolderExists(folderspec:=s) = False Then
                    fs.Createfolder s
                End If
    
            End If
        Next
    Next